* The Stata code below produces the results in 
* Aghion, Philippe, Nick Bloom, Richard Blundell, Rachel Griffith and Peter Howitt (2005), "Competition and innovation: an inverted U relationship" Quarterly Journal of Economics  May 2005, Vol. 120, No. 2, pp. 701-728

u "abbgh_data.dta"

global RD    = "rd_yUSA rd_yUSA_2 rd_yFRA rd_yFRA_2" 
global RDTFP = "rd_yUSA rd_yUSA_2 tfpUSA tfpUSA_2 rd_yFRA rd_yFRA_2 tfpFRA tfpFRA_2 tfpFRAdum" 
global IMP   = "imp_yUSA imp_yUSA_2 imp_yFRA imp_yFRA_2"
global EXP   = "exp_yUSA exp_yUSA_2 exp_yFRA exp_yFRA_2"
global LIMU  = "muUt muUt2 liUSA liUSA_2 muFt muFt2 liFRA liFRA_2"

global RD1    = "rd_yUSA1 rd_yUSA1_2 rd_yFRA1 rd_yFRA1_2" 
global RDTFP1 = "rd_yUSA1 rd_yUSA1_2 tfpUSA1 tfpUSA1_2 rd_yFRA1 rd_yFRA1_2 tfpFRA1 tfpFRA1_2 tfpFRA1dum" 
global IMP1   = "imp_yUSA1 imp_yUSA1_2 imp_yFRA1 imp_yFRA1_2"
global EXP1   = "exp_yUSA1 exp_yUSA1_2 exp_yFRA1 exp_yFRA1_2"
global LIMU1  = "muUt muUt2 liUSA1 liUSA1_2 muFt muFt2 liFRA1 liFRA1_2"

global POL1 = "SMPhighD SMPmedD car per brew"
global POL2 = "tele phar text raz steel ord"

global Xex "yr* iii*"

global X "Lc_2 Fl1Lc_2 Fl2Lc_2 Fl3Lc_2 Fl4Lc_2"

global XF   "L LeF   L_2 $Xex ici lucas unilev gec pilk gkn btr sandn"
global XFnn "L LeFnn L_2 $Xex ici lucas unilev gec pilk gkn btr sandn"

global XFc   "Lc LceF   Lc_2 $Xex"
global XFnnc "Lc LceFnn Lc_2 $Xex"

global XFa   "ALPHA ALPHAeF   ALPHA_2 $Xex ici lucas unilev gec pilk gkn btr sandn"
global XFnna "ALPHA ALPHAeFnn ALPHA_2 $Xex ici lucas unilev gec pilk gkn btr sandn"


**** Col (1) Table I
poisson patcw Lc Lc_2  yr*
test Lc Lc_2
gen curveyear = exp(_b[_cons] + _b[Lc]*Lc + _b[Lc_2]*Lc_2 )

**** Col (2) Table I, and Figure II
poisson patcw Lc Lc_2 $Xex
test Lc Lc_2
gen curveindyear = exp(_b[_cons] + _b[Lc]*Lc + _b[Lc_2]*Lc_2 )
lab var curveindyear "Fitted exponential quadratic"

**** Col (4) Table I
* first stage
reg Lc $RDTFP $IMP1 $EXP1 $LIMU1 $POL1 $POL2 $Xex
test $POL1 $POL2
test $RDTFP $IMP1 $EXP1 $LIMU1 
predict LceF    ,resid
* regression with control function
poisson patcw Lc LceF Lc_2 $Xex
test Lc Lc_2
gen curvecontrol = exp(_b[_cons] + _b[Lc]*Lc + _b[Lc_2]*Lc_2 )
lab var curvecontrol "Control function curve"


**** Col (1) Table III
reg NN Lc yr*

**** Col (2) Table III
reg NN Lc yr* iii*


**** Col (3) Table III
gen Lc_morec = Lc*(split==1)
gen Lc_2_morec = Lc_2*(split==1)
poisson patcw Lc Lc_2 Lc_morec Lc_2_morec yr*
test Lc Lc_2
test Lc_morec Lc_2_morec

**** Col (4) Table III
poisson patcw Lc Lc_2 Lc_morec Lc_2_morec yr* iii*
test Lc Lc_2
test Lc_morec Lc_2_morec
gen curveall = exp(_b[_cons] + _b[Lc]*Lc + _b[Lc_2]*Lc_2 )
gen curvemore= exp(_b[_cons] +  _b[Lc]*Lc + _b[Lc_2]*Lc_2 + _b[Lc_morec]*Lc_morec + _b[Lc_2_morec]*Lc_2_morec )
lab var curveall "All industries"
lab var curvemore "More neck-and-neck"

**** Figure I
egen p10 = pctile(patcw),p(10)
egen p90 = pctile(patcw),p(90)
so Lc
gr7 curveindyear patcw Lc if patcw<p90&patcw>p10, s(.O) c(l.) xlab(0.85,0.9,0.95,1) ylab l1("Citation weighted patents") 

**** quadratic spline for Figure II
poisson patcw $X $Xex
test    Lc_2 Fl1Lc_2 Fl2Lc_2 Fl3Lc_2 Fl4Lc_2
gen pn2c = exp(_b[_cons] + _b[Lc_2]*Lc_2 + _b[Fl1Lc_2]*Fl1Lc_2 + _b[Fl2Lc_2]*Fl2Lc_2 + _b[Fl3Lc_2]*Fl3Lc_2 + _b[Fl4Lc_2]*Fl4Lc_2) if e(sample)
lab var pn2c "Spline - ind"

**** Figure II
gr7 curveindyear pn2c  Lc, s(OT) c(ll) xlab(0.85,0.9,0.95,1) ylab l1("Citation weighted patents")

**** Figure III
gr7 curveall curvemore Lc if Lc_morec~=0,xlab ylab xline(0.85,1)